License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package whiteout;

import javafx.animation.Timeline;
import javafx.animation.Interpolator;
import javafx.scene.Group;
import javafx.scene.input.MouseEvent;
import javafx.scene.paint.Color;
import javafx.scene.shape.Rectangle;
import javafx.scene.text.*;


public class BlueButton extends Group {
    public-init var env: Env;
    public-init var text: String;
    // We will add a 2 pixel shadow.
    public-init var width = env.blueButtonWidth - 2;
    public-init var height = env.blueButtonHeight - 2;
    var strokeAlpha = 0.3;

    def fade = Timeline {
        keyFrames: [
            at(0s)   { strokeAlpha => 0.3 tween Interpolator.LINEAR },
            at(0.5s) { strokeAlpha => 1.0 tween Interpolator.LINEAR }
        ]
    };

    init {
        def textNode = Text {
             content: text
             textOrigin: TextOrigin.TOP
             fill: Color.WHITE
             font: env.smallFont
        };

        // center the text in the button
        textNode.translateX = (width - textNode.layoutBounds.width) / 2;
        textNode.translateY = (height - textNode.layoutBounds.height) / 2 + 1;

        content = [
            // This creates a shadow on the bottom and right of the button
            Rectangle {
                fill: Color.rgb(0x30, 0x30, 0x30)
                translateX: 2
                translateY: 2
                width: width
                height: height
                arcWidth: 6
                arcHeight: 6
            },
            Rectangle {
                fill: env.blueGrad
                width: width
                height: height
                arcWidth: 6
                arcHeight: 6
                stroke: bind Color{
                    red: 1,
                    green: 1,
                    blue: 1,
                    opacity: strokeAlpha
                }

                onMouseEntered:function(e) {
                    fade.rate = 10.0;
                    fade.play();
                }

                onMouseExited:function(e) {
                    fade.rate = -10.0;
                    fade.play();
                }
            },
            textNode
        ];
    }
}