License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package tweeter.view.list;

import javafx.scene.control.ScrollBar;
import javafx.scene.CustomNode;
import javafx.scene.Group;
import javafx.scene.layout.VBox;
import javafx.scene.Node;
import javafx.scene.shape.Rectangle;
import javafx.scene.input.KeyCode;
import javafx.util.Math;
import tweeter.view.list.ListItem;
import tweeter.view.TweeterView;

/**
 * @author Rakesh Menon
 */

public class ListView extends CustomNode {

    def rect_y = 2;
    def rect_widthpadding = 10;
    def rect_heightpadding = 2;
    def listview_spacing = 0;
    def listview_layoutX = 2;
    def listview_layoutYpadding = 2;
    def scrollbar_layoutXpadding = 10;
    def scrollbar_layoutY = 0;

    public var listItem:ListItem[];
    public var height = 276.0;
    public var itemWidth = 218.0;
    public var selectedListItem:ListItem;
    override var focusTraversable = true;
    
    var scrollBar:ScrollBar = ScrollBar {
        layoutX: bind (TweeterView.width - scrollbar_layoutXpadding - scrollBar.width)
        layoutY: scrollbar_layoutY
        min: 0
        max: bind Math.max((listView.boundsInLocal.height - height), 0)
        vertical: true
        height: bind height
        blockIncrement: bind ListItem.height
        focusTraversable: false
        blocksMouse: true
    };


    var listView = VBox {
        spacing: listview_spacing
        layoutX: listview_layoutX
        layoutY: bind -(scrollBar.value) + listview_layoutYpadding
        content: bind listItem
    };

    override var onKeyPressed = function(e) {
        if(e.code == KeyCode.VK_UP) {
            scrollBar.adjustValue(-1);
        } else if(e.code == KeyCode.VK_DOWN) {
            scrollBar.adjustValue(1);
        }
    }

   override function create() : Node {
        Group {
            content: [
                Group {
                    content: [ listView ]
                    // Clip for ListView
                    clip:Rectangle {
                        y: rect_y
                        width: bind TweeterView.width - rect_widthpadding
                        height: bind height - rect_heightpadding
                    }
                },
                scrollBar
            ]
        }
    }
}