License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

/*
 * Cell.fx
 *
 * Created on Mar 7, 2009, 2:15:34 PM
 */

package sudoku;

import javafx.scene.Cursor;
import javafx.scene.CustomNode;
import javafx.scene.Node;
import javafx.scene.paint.Color;
import javafx.scene.shape.Rectangle;
import javafx.scene.text.TextAlignment;
import javafx.scene.text.Text;
import javafx.scene.text.TextOrigin;
import javafx.scene.layout.Container;
import javafx.scene.layout.LayoutInfo;

/**
 * @author Rakesh Menon
 */

public class DataCell extends Container {

    public var data = 0;
    public var cellText = "";
    def _rectXY = 3;
    def _rectWdthHgtPadding = 6;

    public var show = false on replace {
        if(show) {
            cellText = "{data}";
            cursor = Cursor.DEFAULT;
        }
    }

    public var error = false on replace {
        if(error) {
            text.fill = Color.BLACK;
        }
    }

    //Properties of each row
    public var row = 0 on replace {
        layoutY = row * height;
        if((row mod 3) == 0) {
            translateY += 2;
        }
    }

    //Properties of each column
    public var col = 0 on replace {
        layoutX = col * width;
        if((col mod 3) == 0) {
            translateX += 2;
        }
    }

    var defRect = Rectangle {
        styleClass: "normalDataCell"
        width: width
        height: width
    }

    var selRect = Rectangle {
        x: _rectXY
        y: _rectXY
        width: width-_rectWdthHgtPadding
        height: height-_rectWdthHgtPadding
        visible: bind selected
        styleClass: "selectedDataCell"
    }
    var errorRect = Rectangle {
        x : _rectXY
        y : _rectXY
        width: width-_rectWdthHgtPadding
        height: height-_rectWdthHgtPadding
        visible: bind error
        styleClass: "errorDataCell"
    }

    //Text for each number to be displayed on the cell
    var text: Text = Text {
        content: bind cellText
        layoutX: bind (defRect.width - text.boundsInLocal.width) / 2.0
        layoutY: bind (defRect.height - text.boundsInLocal.height) / 2.0
        textOrigin: TextOrigin.TOP
        textAlignment: TextAlignment.CENTER
        styleClass: "dataText"
    }

    public var selected = false on replace {
        if(selected) {
            text.fill = defRect.fill;
        } else if(show) {
            text.fill = Color.BLACK;
        } else {
            text.fill = selRect.fill;
        }
    }

    public function reset() {
        cellText = "";
        error = false;
        selected = false;
        show = false;
        text.fill = Color.BLACK;
    }

   init {
       layoutInfo = LayoutInfo {
            width : 30
            height : 30
       }
        cursor = Cursor.HAND;
        children = [ defRect, selRect, errorRect, text ]
   }
}