FX

/* 
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER
 * Copyright 2009 Sun Microsystems, Inc. All rights reserved. Use is subject to license terms. 
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met:
 *
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer.
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Sun Microsystems nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission.
 * 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
 * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
 * ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
package shoppingservice.view;

import javafx.scene.input.MouseEvent;
import javafx.scene.Group;
import javafx.scene.Node;
import javafx.scene.CustomNode;
import javafx.scene.text.Text;
import javafx.scene.text.Font;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;
import javafx.scene.shape.Line;
import javafx.scene.shape.Rectangle;
import javafx.scene.paint.Color;
import shoppingservice.model.ProductCatalog;
import shoppingservice.Main;
import shoppingservice.Utils;

/**
 * View to display Item in Product List
 */

public def height = 41;
public def width = 240;

def arrowImage = Image { url: "{__DIR__}images/arrow.png" };

public class ListItem extends CustomNode { 
    
    public var product: ProductCatalog on replace {
        if(product != null) {
            productName.content = Utils.trimString(product.productName, 25);
            price.content = "${product.priceFrom} - ${product.priceTo}";
            visible = true;
        } else {
            visible = false;
        }
    };
    
    var productName = Text {
        x: 10
        y: 13
        font: Font { name: "Bitstream Vera Sans Bold" size: 11 }
        fill: Color.WHITE
        content: ""
    };
    
    var price = Text {
        x: 10
        y: 30
        font: Font { name: "Bitstream Vera Sans Bold" size: 11 }
        fill: Color.rgb(124, 219, 78)
        content: "0.0"
    };
    
    var arrow = ImageView {
        image: arrowImage
        x: width - 20
        y: (height - 15)/2
        fitWidth: 15
        fitHeight: 15
    };
        
    def BG_SEL_COLOR = Color.rgb(35, 35, 35);
    var bgRect = Rectangle {
        x: 0 y: 0
        width: width height: height
        fill: BG_SEL_COLOR
        stroke: Color.rgb(10, 13, 15)
        strokeWidth: 2.0
        opacity: 0.5
    }
    
    override function create():Node {

        // Opacity/Clip not supported on Mobile, hence fill with transparent color
        if("{__PROFILE__}" == "mobile") { bgRect.fill = Color.TRANSPARENT; }
        
        Group { 
            content: [ 
                bgRect, productName, price, arrow
            ] 
            visible: true
        };
    }
        
    override var onMouseEntered = function(e:MouseEvent) {
        if("{__PROFILE__}" == "mobile") {
            bgRect.fill = BG_SEL_COLOR;
        } else {
            bgRect.opacity = 0.8;
        }
    }
    
    override var onMouseExited = function(e:MouseEvent) {
        if("{__PROFILE__}" == "mobile") {
            bgRect.fill = Color.TRANSPARENT;
        } else {
            bgRect.opacity = 0.5;
        }
    }

    override var onMousePressed = function(e:MouseEvent) {
        Main.productInfoView.product = product;
        Main.productInfoView.show = true;
    }
}