License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

/*
 * MainScreen.fx
 *
 * Created on Dec 22, 2009, 9:56:29 AM
 */

package fxpodcastviewer.ui.desktop;

import javafx.scene.CustomNode;
import javafx.scene.Node;
import javafx.scene.layout.VBox;
import fxpodcastviewer.ui.desktop.ControllBar;
import fxpodcastviewer.media.MediaBox;
import fxpodcastviewer.feed.PodcastMedia;
import fxpodcastviewer.ui.desktop.MediaController;
import fxpodcastviewer.ui.desktop.list.PodcastList;
import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.stage.StageStyle;
import javafx.scene.paint.Color;
import javafx.scene.Group;

/**
 * @author raghunair
 */

public class MainScreen extends CustomNode{

    public var podcastList = PodcastList{};

    var mediaBox:MediaBox = MediaBox{ mediaViewWidth:640 mediaViewHeight:330 };


    public var mediaMeta:PodcastMedia on replace {
        if (mediaMeta != null){
            mediaBox.mediaSourceURL = mediaMeta.mediaURL;
            detailView.media = mediaMeta;
            podcastList.podcasts = mediaMeta.parentFeed.medias;
        }

    }

    var detailView:DetailView = DetailView{ media:mediaMeta player:mediaBox.myPlayer addList:addList}

    var controllBar:ControllBar = ControllBar{ translateY:10 };

    var group:Group = Group{
            
            content:
            [
                VBox{
                translateY:50
                spacing:0
                content:
                    [
                        mediaBox,
                        TitleBar{ titleStr:bind mediaMeta.title detailView:detailView},
                        MediaController{player:mediaBox.myPlayer mediaBox:mediaBox}
                    ]
                },detailView]
    }

    var mainGroup:Group = Group{ content: [controllBar,group]}

    override function create():Node{
        mainGroup
    }

    public function addList():Void{
        delete group from mainGroup.content;
        insert podcastList into mainGroup.content;
    }

    public function restoreControlBar(){
        controllBar.restore();
    }

    public function removeList(){
        delete podcastList from mainGroup.content;
        insert group into mainGroup.content;
        detailView.hide();
    }

}

function run(){
    
    var meta = PodcastMedia{
                    mediaURL:"file:///Users/raghunair/MyFXProjects/bunny2.3gp"
                    image:"{__DIR__}resources/podcast.png"
                    title:"Test title by Raghu Nair"
                    publisher:"Raghu Nair"
                    pubDate:"Thursday, Apr  il 20 2009"
                    data:" don't expect that there are engineers around to fix the issues found in b19 swat."
                         "During the next 2 weeks, it is expected that sqe will\n"

                        "1) Get the test suites ready for b20 build, which contains compiler changes\n"
                        "2) Test b19c as compiler scrum turns out new build\n"
                        "3) Slide in b19 testing when there is no progress for 1) and 2)\n"

                }
     Stage {
                title : "MyApp"
                style:StageStyle.TRANSPARENT
                scene: Scene {
                        width: 640
                        height: 480

                        fill:Color.BLACK
                        content: [MainScreen{ mediaMeta:meta } ]
                        }
            }

}