License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

/*
 * DetailView.fx
 *
 * Created on Dec 22, 2009, 6:58:00 AM
 */

package fxpodcastviewer.ui.desktop;

import javafx.scene.CustomNode;
import javafx.scene.Node;
import javafx.scene.Group;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;
import javafx.scene.layout.VBox;
import javafx.scene.text.*;
import fxpodcastviewer.media.MyPlayer;
import fxpodcastviewer.util.ImageButton;
import fxpodcastviewer.feed.PodcastMedia;
import javafx.scene.paint.Color;
import javafx.scene.layout.HBox;
import javafx.scene.shape.Line;
import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.media.Media;
import javafx.stage.StageStyle;
import javafx.scene.shape.Rectangle;
import fxpodcastviewer.ui.desktop.MainScreen;
import fxpodcastviewer.Main;

/**
 * @author raghunair
 */

public class DetailView extends CustomNode{
    var width = 640;
    var height = 380;
    var iconSize = 30;

    public var media:PodcastMedia;

    public var player:MyPlayer;

    public var addList:function();

    public function hide(){
        visible = false;
    }

    public function show(){
        visible = true;
    }

    var defaultImage = Image{ url:"{__DIR__}resources/podcast.png"}

    var image:ImageView = ImageView{
        image:defaultImage
        fitHeight:100
        fitWidth:133.3
    }

    var podDetails:VBox = VBox{
        spacing:5
        content: [
          Text{
            content:bind media.title
            font:bind Font.font("Arial", FontWeight.BOLD, 18);
            fill:Color.WHITE
          },

          Text{
            content:bind "By {media.publisher}"
            font:bind Font.font("Arial", 18);
            fill:Color.WHITE
          },
          Text{
            content:bind media.pubDate
            font:bind Font.font("Arial", 18);
            fill:Color.WHITE
          },
          Text{
            content:bind player.durationInfo
            fill:Color.WHITE
            font:bind Font.font("Arial", FontWeight.BOLD, 18);
          },
        ]
    }

    var back:ImageButton = ImageButton{
        translateX:640 - iconSize - 20
        translateY:10
        fitWidth:iconSize
        fitHeight:iconSize
        normalImage:Image{ url:"{__DIR__}resources/prev.png"}
        action:function(){
            hide();
        }
    }

    var upperGroup = Group{
        translateX:10
        content: [ getLine(),HBox{
                    translateY:10
                    spacing:10
                    content: [image,podDetails]
                 },back]
    }

    var summary:Text = Text {
        translateX:10
        content:bind media.data
        font:Font.font("Arial",18)
        wrappingWidth:620
        fill:Color.WHITE
    }


    function getLine(){
        Line{
            stroke:Color.GRAY
            startX:0
            startY:0
            endX:620
            endY:0
        }

    }


    var more = Text{
        translateY:30
        translateX:10
        content:"More from this podcast"
        font:Font.font("Arial", FontWeight.BOLD, 20);
        fill:Color.WHITE
    }

    var moreButton = ImageButton{
        translateX:640 - iconSize - 10
        translateY:10
        normalImage:Image{ url:"{__DIR__}resources/play.png" }
        fitHeight:iconSize
        fitWidth:iconSize
        action:function(){
            Main.list();
        }

    }

    override function create():Node{
        hide();
        var line1= getLine();
        line1.translateX = 10;
        var line2= getLine();
        line2.translateX = 10;
        line2.translateY = 45;
        var listAll =Group{
            translateY:height-50
            content: [more,moreButton,line1,line2]
        }

        Group {
            translateY:50
            content: [
                Rectangle{
                    width:width
                    height:height
                    fill:Color.BLACK
                    stroke:Color.TRANSPARENT
                },

                VBox{
                translateY:5
                spacing:10
                content: [upperGroup,summary
                        ]},listAll]
        }
    }

}

function run(){
            Stage {
                title : "MyApp"
                style:StageStyle.TRANSPARENT
                scene: Scene {
                        width: 640
                        height: 480

                        fill:Color.BLACK
                        content: [ DetailView{
                                    translateY:50
                                    media:PodcastMedia{
                                        title:"Test title by Raghu Nair"
                                        publisher:"Raghu Nair"
                                        pubDate:"Thursday, April 20 2009"
                                        data:" don't expect that there are engineers around to fix the issues found in b19 swat."
                                             "During the next 2 weeks, it is expected that sqe will\n"

                                            "1) Get the test suites ready for b20 build, which contains compiler changes\n"
                                            "2) Test b19c as compiler scrum turns out new build\n"
                                            "3) Slide in b19 testing when there is no progress for 1) and 2)\n"

                                    }
                                    player:MyPlayer{
                                        media:Media{
                                                source:"file:///Users/raghunair/MyFXProjects/bunny2.3gp"
                                                }
                                    }

                                   }
                                 ]
                }
        }


}