License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

import javafx.animation.KeyFrame;
import javafx.animation.Timeline;

import javafx.scene.paint.Color;

import javafx.scene.Scene;
import javafx.stage.Stage;

def rnd = java.util.Random { }
def scene = Scene {
  fill: Color.BLACK
  width:  600
  height: 400
}

Stage {
  title: "Magnetism (JavaFX sample)"
  scene: scene
  override var x on replace old {
    def diff = old - x;
    if (diff != 0)
      for (node in scene.content)
        node.translateX += diff;
  }
  override var y on replace old {
    def diff = old - y;
    if (diff != 0)
      for (node in scene.content)
        node.translateY += diff;
  }
}

// initialize scene after updating its bounds
scene.content = for (i in [1..10]) Ball {
  sign: 0.5 < rnd.nextDouble()
  radius: 10 + 20 * rnd.nextDouble()
  translateX: scene.width  * rnd.nextDouble()
  translateY: scene.height * rnd.nextDouble()
}

// start timeline for 25 frames per second
Timeline {
  repeatCount: Timeline.INDEFINITE
  keyFrames: KeyFrame {
    time: 40ms
    action: function() {
      var n = scene.content.size() - 2;
      for (i in [0..n]) {
        def ball = scene.content[i] as Ball;
        for (j in [i..n]) {
           ball.process(scene.content[j+1] as Ball)
        }
      }
      for (node in scene.content)
        (node as Ball).update()
    }
  }
}.play()