License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package imageloader;

import javafx.scene.image.*;
import javafx.scene.shape.*;
import javafx.scene.*;
import javafx.scene.paint.*;
import javafx.scene.transform.*;
import javafx.animation.*;

public class ImageLoadingSpinner extends CustomNode {
    public var image:Image;
    public var width:Number = 50;
    public var height:Number = 50;

    def spinner = Group {
        content: [
            // grey background
            Rectangle {
                width: bind width
                height: bind height
                fill: Color.DARKGRAY
            },
            //spinning circles
            Group {
                translateX: bind width / 2
                translateY: bind height / 2
                content: for(n in [0..3]) {
                    Circle {
                        fill: Color.rgb(255, 255, 255, 0.5)
                        transforms: bind Transform.rotate(angle + n*90, 0, 0)
                        centerX: 30
                        centerY: 30
                        radius: 50
                    }
                }
            }
        ]
    };

    var angle = 0;
    var spinnerAnim:Timeline = Timeline {
        repeatCount: Timeline.INDEFINITE
        keyFrames: [
            at(0s) { angle => 0 tween Interpolator.LINEAR },
            at(2s) { angle => 360 tween Interpolator.LINEAR }
        ]
    };
    
    var fadeAnim:Timeline = Timeline {
        keyFrames: [
            at(0s) { spinner.opacity => 1.0 tween Interpolator.LINEAR },
            KeyFrame {
                time: 0.5s
                values: spinner.opacity => 0.0 tween Interpolator.LINEAR
                action:function():Void {
                    spinnerAnim.stop();
                }
            },
        ]
    };

    var progress = bind image.progress on replace {
        if(progress == 0) {
            spinner.opacity = 1.0;
            spinnerAnim.play();
        } else if(progress >= 100) {
            fadeAnim.playFromStart();
        }
    };

    override public function create():Node {
        return Group {
            content: [
                ImageView {
                    image: bind image
		    fitHeight: bind height
		    preserveRatio: true
		    smooth: true
                    cache: false
                },
                spinner
            ]
        }
    }

}