License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package forecasting_mobile;

import javafx.stage.Stage;
import javafx.stage.StageStyle;
import javafx.stage.Screen;
import javafx.scene.image.Image;
import javafx.scene.image.ImageView;
import javafx.scene.input.MouseEvent;
import javafx.scene.layout.HBox;
import javafx.scene.layout.LayoutInfo;
import javafx.scene.paint.Color;
import javafx.scene.text.Font;
import javafx.scene.text.Text;
import javafx.scene.layout.Stack;
import javafx.geometry.HPos;
import javafx.scene.Cursor;
import javafx.scene.Scene;

// @author JavaFX Samples Team

var stageDragInitialX:Number;
var stageDragInitialY:Number;
public var stageX: Number = 200;
public var stageY: Number = 200;
package def STAGE_WIDTH:Number = if(__PROFILE__ == "mobile") Screen.primary.visualBounds.width else if (__PROFILE__ == "browser") 240 else 640;
package def STAGE_HEIGHT:Number = if(__PROFILE__ == "mobile") Screen.primary.visualBounds.height else if (__PROFILE__ == "browser") 320 else 485;
var chart = Chart{};

var header = Stack {
    content: [
        ImageView {
            fitWidth: bind STAGE_WIDTH
            image: Image {
                url: "{__DIR__}images/elements_top.png"
            }
            onMousePressed:function(e:MouseEvent):Void {
                stageDragInitialX = e.screenX - stageX;
                stageDragInitialY = e.screenY - stageY;
            }
            onMouseDragged:function(e:MouseEvent):Void {
                stageX = e.screenX - stageDragInitialX;
                stageY = e.screenY - stageDragInitialY;
            }
        },
        HBox {
            spacing: 15
            content: [
                ImageView {
                    image: Image {
                        url: "{__DIR__}images/Java_Logo.png"
                    }
                },
                Text {
                    translateY: 15
                    fill: Color.WHITE
                    font: Font {
                        size: 12
                        name: "Arial Bold"
                    }
                    content: "3-Day Forecast, NewYork,US"
                },
            ]
        }
    ]
}
var footer = Stack {
    layoutY: Main.STAGE_HEIGHT - 45
    layoutInfo: LayoutInfo {
        width: STAGE_WIDTH
    }
    content: [
        ImageView {
            fitWidth: bind STAGE_WIDTH
            image: Image {
                url: "{__DIR__}images/elements_bottom.png"
            }
        },
        HBox {
            translateY: 12
            cursor: Cursor.HAND
            hpos: HPos.CENTER
            width: STAGE_WIDTH
            spacing: 10
            content : [
                ImageView {
                    cache: true
                    image: Image {
                        url: "{__DIR__}images/Button_Exit.png"
                    }
                    onMouseClicked: function(e:MouseEvent ):Void {
                        if (__PROFILE__ != "browser")
                            FX.exit();
                    }
                },
                ImageView {
                    cache: true
                    image: Image {
                        url: "{__DIR__}images/Button_Refresh.png"
                    }
                    onMouseClicked:function(e:MouseEvent):Void {
                        chart.weather.getDataFromWS();
                        chart.bubbleVisiblity = false;
                    }
                },
            ]
        }
    ]
}
public function run() {
    chart.weather.getDataFromWS();
    Stage {
        x: bind stageX
        y: bind stageY
        title: "Chart Examples"
        style: StageStyle.UNDECORATED
        scene: Scene {
            content: [
                ImageView {
                    fitWidth: bind STAGE_WIDTH
                    fitHeight: bind STAGE_HEIGHT
                    image: Image {
                        url: "{__DIR__}images/background_3.png"
                    }
                },
                chart,
                header,
                footer,
            ]
        }
    }
}