License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package fishsim;
import javafx.scene.shape.*;
import javafx.animation.*;
import javafx.scene.paint.*;
import javafx.scene.*;

/**
 * Generates ripples on the screen every 0.5 seconds or whenever
 * the createRipple method is called. Ripples grow and fade out
 * over 3 seconds
 */

class Ripple extends Circle {
    override var stroke = Color.rgb(200,200,255);
    override var fill = null;
    override var centerX = 100;
    override var centerY = 100;
    var anim = Timeline {
        keyFrames: [
            at(0s) { radius => 0 tween Interpolator.LINEAR },
            at(1s) { opacity => 1.0 tween Interpolator.LINEAR },
            at(3s) { radius => 100 tween Interpolator.LINEAR },
            at(3s) { opacity => 0.0 tween Interpolator.LINEAR }
        ]
    }
}

public class RippleGenerator extends CustomNode {
    var ripples:Node[];
    public var generatorCenterX = 100.0;
    public var generatorCenterY = 100.0;
    
    override public function create():Node {
        return Group{
            content: bind ripples;
        }
    }
    
    public function createRipple():Void {
        var rip = Ripple { 
            centerX: generatorCenterX
            centerY: generatorCenterY
        };
        insert rip into ripples;
        rip.anim.play();
        var remover = Timeline {
            keyFrames: [
                KeyFrame { 
                    time: 3s 
                    action:function() { 
                        delete rip from ripples; 
                        rip.anim.stop(); 
                    } 
                },
            ]
        };
        remover.play();
    }
    
    public var generate = Timeline {
        keyFrames: KeyFrame {
            time: 0.5s
            action: createRipple
        }
        repeatCount: Timeline.INDEFINITE
    }
}