License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package fishsim;

import javafx.animation.*;
import javafx.stage.*;
import javafx.scene.input.*;
import javafx.scene.*;
import javafx.scene.paint.*;
import javafx.scene.shape.*;
import javafx.scene.text.*;
import javafx.animation.*;


var width:Number = bind scene.width;            // Width are updated when the screen is rotated or resized
var height:Number = bind scene.height;          // Height are updated when the screen is rotated or resized
var fish = Fish {
    visible: false
};
fish.wag.play();

var ripper = RippleGenerator { };

var textOverlay:Text = Text {
    fill: Color.WHITE
    font:Font { size: 16 }
    content: "Click to create ripples"
    y: 70
        translateX: bind (width-textOverlay.boundsInLocal.width)/2
    opacity: 1.0
    visible: true;
    };

var textFade = Timeline {
    keyFrames: [
        at(1s) { textOverlay.opacity=>0.0 },
        KeyFrame {
            time: 1s
            action:function() {
                textOverlay.visible = false
            }
        }
    ]
};

var scene: Scene = Scene {

    fill: RadialGradient {
        radius:500
        focusX: 0
        focusY: 0
        centerX: 300
        centerY: 300
        proportional: false
        stops: [
            Stop {
                offset: 0
                color: Color.BLACK
            },
            Stop {
                offset: 1
                color: Color.BLUE
            },
        ]
    }

    content: Group {
        content: [
        // a colorful background
        fish,
        ripper,
        Rectangle {
            fill: Color.rgb(255,255,255,0.0)
            width: bind width
            height: bind height
            onMousePressed: function(e:MouseEvent) {
                ripper.generatorCenterX= e.x;
                ripper.generatorCenterY= e.y;
                ripper.createRipple();
                ripper.generate.play();
                fish.goTo(e.x,e.y);
                if(textOverlay.visible) {
                    textFade.play();
                }
            }
            onMouseDragged: function(e:MouseEvent) {
                ripper.generatorCenterX= e.x;
                ripper.generatorCenterY= e.y;
                fish.goTo(e.x,e.y);
            }
            onMouseReleased: function(e:MouseEvent) {
                ripper.generate.stop();
            }
        },
        textOverlay
        ]
    }
};


Stage {
    width: 600
    height: 400
    scene: scene
}

var t: Timeline = Timeline {
    repeatCount: Timeline.INDEFINITE
    keyFrames: KeyFrame {
        time: 100ms
        action: function() {
            if(scene.width != 0) {
                fish.visible = true;
                fish.translateX = scene.width/2;
                fish.translateY = 100;
                t.stop();
            }
        }
    }
}
t.play();