License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package effectsplaygroundmobile;

import javafx.scene.*;
import javafx.scene.input.*;
import javafx.scene.shape.*;
import javafx.scene.paint.*;
import javafx.scene.image.*;


public class ImageSlider extends CustomNode {
    public var scaleFactor = 1.0;

    public var minimum = 0.0;
    public var maximum = 100.0;
    public var value = 50.0 on replace {
        if(value < minimum) {
            value = minimum;
        }
        if(value > maximum) {
            value = maximum;
        }
    }

    public var sliderImage: Image = Image {url: "{__DIR__}images/slider.png" }
    public var knobImage: Image = Image {url: "{__DIR__}images/slider-knob.png" }
    var slider_width = bind (sliderImage.width)*scaleFactor;
    var thumb_width = bind (knobImage.width)*scaleFactor;

    function setValue(x:Number):Void {
        var pos = x;
        if(pos < thumb_width/2) { pos = thumb_width/2; }
        if(pos > slider_width-thumb_width/2) { pos = slider_width-thumb_width/2; };
        var v = ((pos-thumb_width/2)/(slider_width-thumb_width))*(maximum-minimum);
        value = v;
    }

    var position = bind ((slider_width - thumb_width) * value) / (maximum - minimum);

    override public function create():Node {
        Group {
            content: [
                Group {
                    content: [
                        ImageView {
                            y: bind (knobImage.height-sliderImage.height)/2
                            image: sliderImage
                            onMousePressed: function(e:MouseEvent):Void {
                                setValue(e.x);
                            }
                            onMouseDragged: function(e:MouseEvent):Void {
                                setValue(e.x);
                            }
                            fitWidth: bind (sliderImage.width)*scaleFactor
                            fitHeight: bind (sliderImage.height)*scaleFactor
                        },
                        ImageView {
                            x: bind position
                            image: knobImage
                            fitWidth: bind (knobImage.width)*scaleFactor
                            fitHeight: bind (knobImage.height)*scaleFactor
                        },
                    ]
                }
            ]
        }
    }

}