License text 

/*
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER 
 * Copyright  2008, 2010 Oracle and/or its affiliates.  All rights reserved. 
 * Use is subject to license terms.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without 
 * modification, are permitted provided that the following conditions are met: 
 * 
 *   * Redistributions of source code must retain the above copyright notice, 
 *     this list of conditions and the following disclaimer. 
 *
 *   * Redistributions in binary form must reproduce the above copyright notice,
 *     this list of conditions and the following disclaimer in the documentation
 *     and/or other materials provided with the distribution.
 *
 *   * Neither the name of Oracle Corporation nor the names of its contributors 
 *     may be used to endorse or promote products derived from this software 
 *     without specific prior written permission. 
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 
 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR 
 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT 
 * OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, 
 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; 
 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF 
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
 */

    

package dukeman;

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.paint.*;

//@author Pavel Porvatov

// Instance of the MainFrame class
public var mainFrame: MainFrame;

function run(__ARGS__ : String[]) {
    // Initialization should be the first
    Config.initialize();

    mainFrame = MainFrame {
        title: "Dukeman"
        resizable: false

        scene: Scene {
            fill: Color.BLACK
            width: Config.SCREEN_WIDTH
            height: Config.SCREEN_HEIGHT
        }
    }

    mainFrame.state = 0;                    // Run splash
}

public class MainFrame extends Stage {
    var splash:Splash;                      // Instance of splash (if exists)

    var level:Level;                        // Instance of level (if exists)

    public var lifeCount:Integer;           // Number of lifes

    public var score:Integer;               // Current score
    public var highScore:Integer = 10000;

    // Initializes game (lifes, scores etc)
    public function startGame() {
        lifeCount = 2;
        score = 0;
        state = 1;
    }

    // Current state of the game. The next values are available
    // 0 - Splash
    // 1.. - level
    public var state: Integer = -1 on replace {
        if (state >= 0) {
            splash.stop();
            level.stop();

            splash = null;
            level = null;

            if (state == 0) {
                splash = Splash {};

                splash.start();
            } else {
                level = Level {
                    level: LevelData.getLevelData((state - 1) mod
                        LevelData.getLevelsCount() + 1)
                }

                level.start();
            }
        }
    };
}