Legal Terms and Copyright Notice
/* 
 * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER
 * 
 * Copyright © 2010, Oracle and/or its affiliates. All rights reserved.
 * Oracle is a registered trademark of Oracle Corporation and/or its affiliates. 
 * Oracle and Java are registered trademarks of Oracle and/or its affiliates. 
 * Other names may be trademarks of their respective owners.
 * 
 * This file is available and licensed under the following license:
 * 
 * Redistribution and use in source and binary forms, with or without modification, 
 * are permitted provided that the following conditions are met:

 *   *  Redistributions of source code must retain the above copyright notice, 
        trademark notice, this list of conditions, and the following disclaimer.

 *   *  Redistributions in binary form must reproduce the above copyright notice, 
        trademark notice, this list of conditions, and the following disclaimer in 
        the documentation and/or other materials provided with the distribution.

 *   *  Neither the name of Oracle nor the names of its contributors may be used 
        to endorse or promote products derived from this software without specific 
        prior written permission.
 
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED 
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. 
 * IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, 
 * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, 
 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES LOSS OF USE, 
 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF 
 * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE 
 * OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE.
 */

package smartcontrols;

import javafx.scene.CustomNode;
import javafx.scene.Group;
import javafx.scene.Node;
import javafx.scene.control.ScrollBar;
import javafx.scene.layout.Resizable;
import javafx.scene.paint.Paint;
import javafx.scene.shape.Rectangle;

public class ScrollPane extends Resizable, CustomNode {
  public var background: Paint;
  public var border: Number;
  public var content: Node;

  def bounds = Bounds {
    content: bind content
  }

  def w: Number = bind bounds.width + border + border + vsb.width;
  override function getPrefWidth(height) {w}

  def h: Number = bind bounds.height + border + border + hsb.height;
  override function getPrefHeight(width) {h}

  def vsb: ScrollBar = ScrollBar {
    min: 0
    max: bind if (h > height) h - height else 0
    visible: bind h > height
    vertical: true
    height: bind height
  }
  def hsb: ScrollBar = ScrollBar {
    min: 0
    max: bind if (w > width) w - width else 0
    visible: bind w > width
    width: bind if (vsb.visible)
      then width - vsb.width
      else width
  }
  override function create() {
    Group {
      clip: Rectangle {
        width: bind width
        height: bind height
      }
      content: [
        Rectangle {
          fill: bind background
          width: bind width
          height: bind height
        }
        Group {
          translateX: bind border - bounds.x - hsb.value
          translateY: bind border - bounds.y - vsb.value
          content: bind content
        }
        Group {
          translateX: bind width - vsb.width
          content: vsb
        }
        Group {
          translateY: bind height - hsb.height
          content: hsb
        }
      ]
      onMouseWheelMoved: function(event) {
        vsb.value += event.wheelRotation * 10
      }
    }
  }
}